アレクサ、お風呂沸かして

/*
 * Espalexaでデバイスを制御する基本形（シンプルな1個のON/OFFスイッチ）を利用して
 * 給湯器をAlexaでonn/offする */

#ifdef ARDUINO_ARCH_ESP32
#include <WiFi.h>
#else
#include <ESP8266WiFi.h>
#endif
#include <Espalexa5.h>

#include <Switches.h>

// prototypes
boolean connectWifi();

//callback functionsコールバック関数のプロトタイプ
void untenChanged(uint8_t brightness);//シンプルなon/offだが、brightnessを使ってみる
void jidouChanged(EspalexaDevice* dev);
void oidakiChanged(EspalexaDevice* dev);

// Change this!!
const char* ssid = "********";
const char* password = "********";

boolean wifiConnected = false;

Espalexa espalexa;

const int untenPin =15;     //D8; output 一次側 フォトカプラ pin#1
const int untLEDPin =13;    //D7; input 二次側(状況のモニター）LED (+)
const int jidouPin =12;     //D6; output 一次側  フォトカプラ pin#1
const int jidLEDPin =14;    //D5; input 二次側(状況のモニター）LED (+)
const int oidakiPin =16;     //D0; output 一次側  フォトカプラ pin#1
const int oidLEDPin =5;     //D1; input 二次側(状況のモニター）LED (+)

const int holdTime = 2000;

unsigned long prev, curr, interval;

Switches sw1(untLEDPin, false, SWITCH_LEVEL);//お湯LED H(消灯) がtrue
Switches sw2(jidLEDPin, false, SWITCH_HtoL);//お風呂LED HからL がtrue
Switches sw3(jidLEDPin, false, SWITCH_LEVEL);//お風呂LED H(消灯) がtrue
Switches sw4(oidLEDPin, false, SWITCH_LEVEL);//おいだきLED H(消灯) がtrue
//           ^   ^         ^
//           |   |         |
//           |   |         +- SWITCH_LEVEL:  ピンがHのとき、trueを返す。
//           |   |            SWITCH_NLEVEL: ピンがLのとき、trueを返す。
//           |   |            SWITCH_HtoL:   ピンの値がHからLに変化したとき(省略時)、trueを返す。
//           |   |            SWITCH_LtoH:   ピンの値がLからHに変化したとき、trueを返す。
//           |   +- true: enable pullup register, false: disable
//           |
//           +--------- pin number

//EspalexaDevice* device3; //this is optional

void setup()
{

  interval = 60*60*1000;   // おいだきを有効とする時間を設定(分)

  Serial.begin(115200);

  pinMode(untLEDPin,INPUT);
  pinMode(untenPin,OUTPUT);
  pinMode(jidLEDPin,INPUT);
  pinMode(jidouPin,OUTPUT);
  pinMode(oidLEDPin,INPUT);
  pinMode(oidakiPin,OUTPUT);


  // Initialise wifi connection
  wifiConnected = connectWifi();

  if(wifiConnected){

    // Define your devices here.
	espalexa.addDevice("Unten", untenChanged); //simplest definition, default state off最 も単純な定義、デフォルトの状態はオフ
	espalexa.addDevice("Jidou", jidouChanged, EspalexaDeviceType::onoff); //non-dimmable device オンオフのみ
  espalexa.addDevice("Oidaki", oidakiChanged, EspalexaDeviceType::onoff); //non-dimmable device オンオフのみ


    espalexa.begin();

  } else
  {
    while (1) {
      Serial.println("Cannot connect to WiFi. Please check data and reset the ESP.");
      delay(2500);
    }
  }
}

void loop()
{
   espalexa.loop();
   delay(1);
   if (sw2()){prev=millis();
     //Serial.println("Start to count new elapsed time");
   }
}


//our callback functionsコールバック関数
void untenChanged(uint8_t brightness) {
//  if (d == nullptr) return; //this is good practice, but not requiredこれは良いやり方ですが、必須ではありません

  //do what you need to do hereここで必要なことをしてください
  //EXAMPLE

  Serial.print("Unten SW changed to ");
  if (brightness > 128 && sw1()){
    Serial.println((String)"ON, brightness "+brightness);
    digitalWrite(untenPin,HIGH);
    delay(holdTime);
    digitalWrite(untenPin,LOW);
    Serial.println((String)"Switch on for "+holdTime/1000+" sec");
  }
  else if (brightness <= 128 && !sw1()) {
    Serial.println((String)"OFF, brightness "+brightness);
      digitalWrite(untenPin,HIGH);
      delay(holdTime);
      digitalWrite(untenPin,LOW);
    Serial.println("Not receiving signal now !");
  }
  else {return;}
}


void jidouChanged(EspalexaDevice* d) {
  if (d == nullptr) return; //this is good practice, but not requiredこれは良いやり方ですが、必須ではありません

  //do what you need to do hereここで必要なことをしてください
  //EXAMPLE

  Serial.print("Jidou changed to ");
  if (d->getValue()){

      if ( sw1() && sw3() ){ //お湯LEDが消灯 かつ お風呂LEDが消灯
        Serial.println("ON");
        digitalWrite(untenPin,HIGH); //お湯LEDを点灯
        delay(holdTime);
        digitalWrite(untenPin,LOW);
        Serial.println((String)"お湯 Switch on for "+holdTime/1000+" sec");
        delay(holdTime);

        Serial.print("and ");
        digitalWrite(jidouPin,HIGH);
        delay(holdTime);
        digitalWrite(jidouPin,LOW);
        Serial.println((String)"お風呂 Switch on for "+holdTime/1000+" sec");
      }
      else if ( !sw1() && sw3() ){ //お湯LEDが点灯 かつ お風呂LEDが消灯
        Serial.println("ON");
        digitalWrite(jidouPin,HIGH);
        delay(holdTime);
        digitalWrite(jidouPin,LOW);
        Serial.println((String)"お風呂 Switch on for "+holdTime/1000+" sec");
      }
  }
  else {
      //if (sw2()) {//お風呂LEDが点灯
        Serial.println("OFF");
        digitalWrite(jidouPin,HIGH);
        delay(holdTime);
        digitalWrite(jidouPin,LOW);
        Serial.println("Not receiving signal now !");
      //}
    //  else if (sw3()) {return;}
  }
}

void oidakiChanged(EspalexaDevice* d) {
  if (d == nullptr) return; //this is good practice, but not requiredこれは良いやり方ですが、必須ではありません

  //do what you need to do hereここで必要なことをしてください
  //EXAMPLE
  Serial.print("Oidaki changed to ");
  if (d->getValue()){
    //Serial.println((String)"d->getValue: "+d->getValue());
    if (!sw1() && sw4() ){ //お湯LEDが点灯 かつ おいだきLEDが消灯
    //Serial.println((String)"!sw1: "+!sw1()+" sw4: "+sw4());
      curr = millis();    // 現在時刻を取得
      //Serial.println((String)"curr: "+curr+" prev: "+prev);
      //Serial.println((String)"sw3: "+sw3()+" Elapsed time: "+(curr - prev)/1000+" sec");
      if ( sw3() && (curr - prev) <= interval) {  // お風呂LEDが消灯 かつ お風呂をつけてから所定時間以下ならば
          Serial.println("ON"); //おいだきスイッチを入れる
          digitalWrite(oidakiPin,HIGH);
          delay(holdTime);
          digitalWrite(oidakiPin,LOW);
          Serial.println((String)"Switch on for "+holdTime/1000+" sec");
      }
    }
  }
  else {
  // if (!sw4()){ //おいだきLEDが点灯しているならば
  //Serial.println((String)"!sw4:"+!sw4());
    Serial.println("OFF");
    digitalWrite(oidakiPin,HIGH);
    delay(holdTime);
    digitalWrite(oidakiPin,LOW);
    Serial.println("Not receiving signal now !");
  }

}


// connect to wifi ? returns true if successful or false if not
boolean connectWifi(){
  boolean state = true;
  int i = 0;

  WiFi.mode(WIFI_STA);
  WiFi.begin(ssid, password);
  Serial.println("");
  Serial.println("Connecting to WiFi");

  // Wait for connection
  Serial.print("Connecting...");
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
    if (i > 20){
      state = false; break;
    }
    i++;
  }
  Serial.println("");
  if (state){
    Serial.print("Connected to ");
    Serial.println(ssid);
    Serial.print("IP address: ");
    Serial.println(WiFi.localIP());
  }
  else {
    Serial.println("Connection failed.");
  }
  return state;
}